How can increase the speed of if statement in VBA Code

Question

I created this if statement as a newbie using VBA to fill out a column in an excel table. The function is functioning well, but it took close to an hour to complete. It needs to move more quickly.

2600 rows make up Table 1. 3200 rows make up Table2.

Can I help me?

Sub PreencherO()

    Dim Current As Worksheet
    Dim His As Worksheet
    Dim Table1 As ListObject
    Dim Table2 As ListObject

    Set Table1 = ThisWorkbook.Worksheets("Current").ListObjects("Data")
    Set Table2 = ThisWorkbook.Worksheets("His").ListObjects("Historical")

    Dim irow As Long
    irow = Table1.ListColumns(1).Range.Rows.Count

    Dim lrow As Long
    lrow = Table2.ListColumns(1).Range.Rows.Count

    Dim i As Integer
    Dim l As Integer

    For i = 2 To irow
        For l = 2 To lrow
            If Table1.DataBodyRange.Cells(i, 6).Value = Table2.DataBodyRange.Cells(l, 6).Value Then
                Table1.DataBodyRange.Cells(i, 20).Value = "OLD"
            End If
        Next l
    Next i
End Sub

I need to increase the speed of it.

Answer 1

Use a Dictionary Object.

Option Explicit

Sub PreencherO()

    Dim Table1 As ListObject, Table2 As ListObject
    Dim i As Long, t0 As Single: t0 = Timer

    With ThisWorkbook
        Set Table1 = .Sheets("Current").ListObjects("Data")
        Set Table2 = .Sheets("His").ListObjects("Historical")
    End With

    Dim dict As Object, key As String
    Set dict = CreateObject("Scripting.Dictionary")

    ' fill dictionary with historic values
    With Table2.DataBodyRange
        'Debug.Print "Table2", .Address
        For i = 1 To .Rows.Count
            key = Trim(.Cells(i, 6))
            If Len(key) > 0 Then
                 dict(key) = i
            End If
        Next
    End With

    ' compare
    Application.ScreenUpdating = False
    With Table1.DataBodyRange
        'Debug.Print "Table1", .Address
        For i = 1 To .Rows.Count
            key = Trim(.Cells(i, 6))
            If dict.exists(key) Then
                 .Cells(i, 20).Value = "OLD"
            End If
        Next
    End With
    Application.ScreenUpdating = True

    MsgBox "Completed in " & Format(Timer - t0, "0.0 secs"), vbInformation
End Sub